Stack Combiner?

[Suraja]

Hello,
I would like to kindly ask you for your help. We have many time lapse Z stacks images (three channels in each of them) and want to combine them into one ("grid" with horizontally aligned channels from one cell and vertically aligned coressponding channels from each cell) . We know that it is possible to combine it with plugin Stack combiner. Is it possible to combine all these combinations in one step, not just by two. Or is there any possibility how to do it more automatically? Or is there any plugin similar to MosaiJ in Fiji but for image sequences (but want to use a MIP not to create mosaic slice by slice)? Hope my request was understandable:-)

Thank you very much for any suggestions and for your kind help!
Suraja

[Pariksheet Nanda]

On Thu, Oct 4, 2012 at 9:43 AM, Suraja <[hidden email]> wrote:
> We have many time lapse Z
> stacks images (three channels in each of them) and want to combine them into
> one ("grid" with horizontally aligned channels from one cell and vertically
> aligned coressponding channels from each cell)

I think what you're looking for is Image > Stacks > Make Montage.
You'll need to run it on a stack of MIPs containing a timelapse of
different cells and then set the montage columns to the number of time
frames for each cell.


> Suraja

Pariksheet

--
ImageJ mailing list: http://imagej.nih.gov/ij/list.html

[Suraja]

Thank you very much for your kind help! But the problem with montage is that I want to play the channels like movies... Hope that I understood correctly.

Thanks again!

[Tiago Ferreira-2]

On 2012.10.04, at 09:43, Suraja wrote:
> We have many time lapse Z stacks images (three channels in each of them) and
> want to combine them into one ("grid" with horizontally aligned channels from
> one cell and vertically aligned coressponding channels from each cell). We know
> that it is possible to combine it with plugin Stack combiner. Is it possible to
> combine all these combinations in one step, not just by two. Or is there any
> possibility how to do it more automatically?

Suraja,

For such a specific usage, just use the macro language to automate what you
would normaly do by hand. Something like:

//---
setBatchMode(true);

// Gather information about the hyperstack.
title = getTitle;
id = getImageID;
Stack.getDimensions(width, height, channels, slices, frames);

// Reduce depth of hyperstack to a single MIP for each frame
run("Z Project...", "start=1 stop="+ slices +" projection=[Max Intensity] all");

// Close original hyperstack
selectImage(id); close;

// Split all channels and convert them to RGB stacks, preserving their LUTs
run("Split Channels");
for (i=1; i<=channels; i++) {
    selectImage(i);
    run("RGB Color");
}

// Combine the first two channels
img1 = "C1-MAX_"+ title;
img2 = "C2-MAX_"+ title;
run("Combine...", "stack1=["+ img1 +"] stack2=["+ img2 +"]");

// Keep appending any remaining channels that may still exist
for (i=3; i<=channels; i++) {
    img = "C"+ i +"-MAX_"+ title;
    run("Combine...", "stack1=[Combined Stacks] stack2=["+ img +"]");
}

setBatchMode("exit & display");
//---

Note that no other images rather than the hyperstack to be processed can be open
when the macro starts

HTH,
-tiago
--
ImageJ mailing list: http://imagej.nih.gov/ij/list.html

[Suraja]

Thank you very much for your help! actually I do not have a lot of experiences with macro language but I will try:-)