// Detection of bubbles and particle body during dissolution.
// Saves ROIs for each image + final results table.
// For Dimitris Karampalis ImageJ mailing list 28 May 2015  
// Dr Kees Straatman, University of Leicester

macro bubbles{
	run("Set Measurements...", "area display redirect=None decimal=3");
	setBatchMode(true);
	dir1 = getDirectory("Select directory with files");
	list1 = getFileList(dir1);
	for (j=0; j<list1.length; j++){
		open(dir1+list1[j]);
		title = getTitle();
		run("Duplicate...", "title="+title+"-1");
		setAutoThreshold("Intermodes dark");
		setOption("BlackBackground", false);
		run("Convert to Mask");
		run("Analyze Particles...", "size=250-Infinity circularity=0.20-1.00 add");
		roiManager("Select", 0);
		run("Fit Circle");
		setBackgroundColor(255, 255, 255);
		run("Clear Outside");
		roiManager("Select", 0);
		roiManager("Delete");
		run("Analyze Particles...", "size=250-Infinity circularity=0.20-1.00 add");
		roiManager("Select", 0);
		run("Fit Ellipse");
		run("Enlarge...", "enlarge=2");
		roiManager("Add");
		roiManager("Select", 0);
		roiManager("Delete");
		roiManager("Select", 0);
		roiManager("Rename", "body");
		run("Measure");
		selectWindow(title);
		setAutoThreshold("Yen dark");
		run("Convert to Mask");
		setForegroundColor(0, 0, 0);
		run("Fill Holes");
		run("Despeckle");
		roiManager("Select", 0);
		setForegroundColor(255, 255, 255);
		run("Fill", "slice");
		run("Select None");
		run("Analyze Particles...", "size=10-Infinity circularity=0.00-1.00 add");
		a= newArray("1");
		b = newArray("0");
		for (i=2; i<roiManager("count"); i++){
			b[0] = i;
			a= Array.concat (a, b);
		}
		roiManager("select", a);
		roiManager("Combine");
		roiManager("Add");
		roiManager("select", a);
		roiManager("Delete");
		roiManager("Select", 1);
		roiManager("Rename", "bubbles");
		run("Measure");
		run("Close All");
		roiManager("Save", dir1+title+".zip");
		roiManager("Deselect");
		roiManager("Delete");
	}
	selectWindow("Results");
	saveAs("txt",dir1+"Results.xls");
	run("Close");
}


--
ImageJ mailing list: http://imagej.nih.gov/ij/list.html