Login  Register

Re: Index of hexagonality?

Posted by gankaku on Jul 07, 2015; 8:11am
URL: http://imagej.273.s1.nabble.com/Index-of-hexagonality-SOLVED-tp5013442p5013447.html

Hi Mr_Sonky,

The attatched Macro prepares the image you sent for the final analysis.
This, might need adjustment depending on how all your other images look
like.
To run the macro you need the "BioVoxxel Toolbox" (
http://www.biovoxxel.de/development/) since it depends on veveral of its
functions.

At the end you can then run the "Neighbor Analysis" macro from the very
same toolbox.
Attatched you also find an image which more or less shows you the procedure
and the outcome.


Hope it helps,
Jan

//-----macro start

original = getTitle();
run("8-bit");
run("Pseudo flat field correction", "blurring=40");
close(original + "_background");
selectWindow(original);
run("Median...", "radius=1");
run("Select None");
run("Duplicate...", "title=Background");
background = getTitle();
run("Median...", "radius=40");
imageCalculator("Subtract", original, background);
selectWindow(original);
run("Enhance Contrast...", "saturated=1 normalize");
run("Auto Threshold", "method=Li white");
run("EDM Binary Operations", "iterations=2 operation=close");
run("Analyze Particles...", "size=50-Infinity show=Masks in_situ");
run("Median...", "radius=5");
run("Invert");
run("Watershed");
run("Voronoi");
setOption("BlackBackground", true);
setThreshold(1, 255);
run("Convert to Mask");
resetThreshold();
run("Invert");

close(background);
selectWindow(original);

//-----macro end

2015-07-07 0:14 GMT+02:00 Mr_Sonky <[hidden email]>:

> Hi all,
>
> I'm looking at some endothelial cells which are meant to be hexagonal and
> tightly packed in nature. With stress and/or trauma, these cells exhbit
> polymorphism - they turn into polygons of varying types. My aim is to
> determine how many cells have lost their hexagon shapes in order to infere
> the severity of the insult. I've attached two samples. The first is simply
> the cellls. The second has a yellow box to highlight a Hexagon whilst the
> red box highlights a cell that has undergone transformation into a a
> different polygon (pentagon - in this instance).
>
> <http://imagej.1557.x6.nabble.com/file/n5013442/Endothelial_Cell.jpg>
>
> <
> http://imagej.1557.x6.nabble.com/file/n5013442/Endothelial_Cell_example.jpg
> >
>
> Any help is appreciated!
>
> NB I have looked at Gary Chinga's shape descriptor plugin and its not what
> I'm looking for =)
>
>
>
>
>
> --
> View this message in context:
> http://imagej.1557.x6.nabble.com/Index-of-hexagonality-tp5013442.html
> Sent from the ImageJ mailing list archive at Nabble.com.
>
> --
> ImageJ mailing list: http://imagej.nih.gov/ij/list.html
>


--

CEO: Dr. rer. nat. Jan Brocher
phone:  +49 (0)6234 917 03 39
mobile: +49 (0)176 705 746 81
e-mail: [hidden email]
info: [hidden email]
inquiries: [hidden email]
web: www.biovoxxel.de

--
ImageJ mailing list: http://imagej.nih.gov/ij/list.html

Endothelial Cell Analysis.png (757K) Download Attachment