Posted by
Herbie on
Aug 26, 2017; 3:21pm
URL: http://imagej.273.s1.nabble.com/Help-with-Image-Stitching-using-Phase-Correlation-tp5019275p5019279.html
Michael,
for shift-detection, the computation of cross-correlation functions is a
brute force approach and not very clever! In fact, you extensively check
the similarity of two signals for _all_ possible relative shifts.
If you compute the correlation function via the FFT, then you need to
enlarge (double) the signal supports in order to be able to detect large
shifts. However, that's not the whole story because in general you will
get a center peak indicating zero shift. You can avoid this and make the
result more stringent if you subtract the signal-mean before enlarging
the signal supports with zeros.
You can check this by trying the following macro:
(watch for mailer-introduced line-breaks)
/////////////////////////////////////////////////////////////////////////
r = getBoolean( "Correlate without mean?" );
setBatchMode( true );
saveSettings();
run( "Set Measurements...", "mean redirect=None decimal=4" );
newImage( "Img-1", "8-bit random", 768, 768, 1 );
run( "Duplicate...", " " );
rename( "Img-2" );
run( "Canvas Size...", "width=512 height=512 position=Center zero" );
run( "32-bit" );
if ( r ) {
getRawStatistics( N, mn );
run( "Subtract...", "value=" + d2s( mn, 9 ) );
}
run( "Canvas Size...", "width=1024 height=1024 position=Center zero" );
selectWindow( "Img-1" );
run( "Canvas Size...", "width=512 height=512 position=Top-Left zero" );
run( "32-bit" );
if ( r ) {
getRawStatistics( N, mn );
run( "Subtract...", "value=" + d2s( mn, 9 ) );
}
run( "Canvas Size...", "width=1024 height=1024 position=Center zero" );
run( "FD Math...", "image1=Img-1 operation=Correlate image2=Img-2
result=Result do" );
getRawStatistics( N, mn, mi, mx );
run( "Divide...", "value=" + d2s( mx, 9 ) );
if ( r ) {
getRawStatistics( N, mn, mi );
setMinAndMax( mi, -mi );
} else {
resetMinAndMax;
}
run( "Find Maxima...", "noise=1 output=[Point Selection]" );
run( "Measure" );
restoreSettings;
setBatchMode( false );
exit();
/////////////////////////////////////////////////////////////////////////
"I understand the concept of converting spatial info in to frequency
domain, but the correlation aspect is a bit of a black box to me!"
In fact, things may not appear evident and require some knowledge of
properties of the Fourier-transformation. The multiplication of two
(complex-valued) Fourier-spectra corresponds to the
convolution-operation applied to the corresponding two signals. The
convolution-operation (an integral expression) is quite similar to the
correlation integral. The difference is just that the coordinates of one
of the two real-valued signals are inverted. This means in the
Fourier-domain that one of the two Fourier-spectra must be taken
conjugate-complex, i.e. its imaginary part receives a negative sign.
"Also, I am finding in my investigations that sometimes the reported
maxima is reported differently (size/2 -cx) or size/2+cx) if the shift
is more or less than size/2 (where size is the padded image size)?"
I'm not sure whether I understand this correctly but be aware that the
correlation operation is _not_ commutative, i.e.
(a corr b) != (b corr a).
Best
Herbie
:::::::::::::::::::::::::::::::::::::::::::
Am 26.08.17 um 13:29 schrieb Michael Ellis:
> Herbie,
>
> Thanks for fast reply, especially on a weekend!
>
> Dramatically is indeed a very relative term here, but my image tiles
> are likely to be 2048 by 2048. If padding is the right way to go then
> I’ll go with that, it just seems surprising as intuitively, by eye, I
> can see the relative translation required from the directly from the
> images so presenting the algorithm with a whole load of padded 0’s
> seems less than obvious.
>
> That said, my grasp of the underlying maths, as said is shaky. I
> understand the concept of converting spatial info in to frequency
> domain, but the correlation aspect is a bit of a black box to me!
>
> Also, I am finding in my investigations that sometimes the reported
> maxima is reported differently (size/2 -cx) or size/2+cx) if the
> shift is more or less than size/2 (where size is the padded image
> size)?
>
> Obviously this is well understood by people brighter than me, since
> the FiJi pairwise stitching algorithm gets it right every time!
>
> — Michael Ellis
>
>
>> On 26 Aug 2017, at 12:17, Herbie <
[hidden email]> wrote:
>>
>> Good day Michael!
>>
>> "This means that the FFT(A) and FFT(B) are also exactly 512x512.
>> Further, using the FFDMath to calculate the inverse transform of
>> the Correlation between FFT(A) and FFT(B) results in an image also
>> of 512x512."
>>
>> That's to the point and a problem with this implementation of the
>> correlation function.
>>
>> "I have tried padding both my images to a size which is the next
>> larger power of two, and for my test data this does resolve the
>> larger shifts, however this hits performance dramatically and I
>> suspect is not the best way to handle this."
>>
>> That's the way to go but could please tell us what "hits
>> performance dramatically" exactly means for you. Of course, a
>> factor 4 in area is a lot but CPUs are fast these days...
>>
>> Computation here of the correlation function of two 1024x1024
>> images is performed in the blink of an eye. Padding is done by
>> "Image >> Adjust >> Canvas Size..."
>>
>> run("Canvas Size...", "width=1024 height=1024 position=Center
>> zero");
>>
>> Regards
>>
>> Herbie
>>
>>
>> ::::::::::::::::::::::::::::::::::::::::::: Am 26.08.17 um 12:53
>> schrieb Michael Ellis:
>>> I am trying to learn about image stitching using cross
>>> correlation. Let say that I have two images A and B that I am
>>> trying to stitch. (you may need to switch to fixed width font to
>>> make these little text pictures work for you) -------
>>> ------- | | | | | A | and | B | | | |
>>> | ------- ------- Considering a shift just in the X
>>> dimension, the maximum shift which would still have a smallest
>>> overlap would be if B is shifted (slightly less than) the width
>>> of A to the right of A, or if B is shifted (slightly less than)
>>> the width of B to the left of A. -------------- | || | |
>>> A || B | | || | -------------- -------------- | ||
>>> | | B || A | | || | -------------- Let A and B both
>>> be exactly 512 by 512 pixels, that is of equal size and a power
>>> of 2 in both X and Y, so the images will need no padding when
>>> their FHT transform is created. This means that the FFT(A) and
>>> FFT(B) are also exactly 512x512. Further, using the FFDMath to
>>> calculate the inverse transform of the Correlation between FFT(A)
>>> and FFT(B) results in an image also of 512x512. But, since in our
>>> case the shift could be anywhere in the range from -511 to + 511,
>>> how can this be represented by the location of maxima drawn from
>>> an image with an X and Y size of 512? I have tried padding both
>>> my images to a size which is the next larger power of two, and
>>> for my test data this does resolve the larger shifts, however
>>> this hits performance dramatically and I suspect is not the best
>>> way to handle this. Anyone able to point me in the right
>>> direction? I understand enough of the mathematics to know that my
>>> grasp on the underlying maths of Fourier transforms is very
>>> rudimentary and shaky, so I am looking for practical advice on
>>> how to utilise the plugins in core ImageJ.jar to best solve the
>>> problem of aligning two images. Many thanks — Michael Ellis --
>>> ImageJ mailing list:
http://imagej.nih.gov/ij/list.html>>
>> -- ImageJ mailing list:
http://imagej.nih.gov/ij/list.html>
>
--
ImageJ mailing list:
http://imagej.nih.gov/ij/list.html