plot profiles for two colors

[Yumi Kumagai]

Hi everyone

Cells were labeled with two fluorescent dyes, and photos for the two
fluorescence
were taken.
I want to compare plot profiles of the two colors for the exact same place.
Could you help me how to have plot profiles for each color using one line?

Thank you in advance.

Yumi Kumagai

--
ImageJ mailing list: http://imagej.nih.gov/ij/list.html

[Anderson, Charles (DNR)]

Yumi,

Google for the ImageJ RGB_Profiler, or use this macro (I don't recall where in the wonderful volumes of ImageJ examples I found it):

// This macro creates three color intensity profile
// plots of line selections on RGB images.

  ylabel = "Intensity";
  if (bitDepth!=24)
     exit("RGB image required");
  setKeyDown("none");
  setRGBWeights(1,0,0); r=getProfile();
  setRGBWeights(0,1,0); g=getProfile();
  setRGBWeights(0,0,1); b=getProfile();
  getVoxelSize(vw, vh, vd, unit);
  x = newArray(r.length);
  for (i=0; i<x.length; i++)
     x[i] = i*vw;
  Plot.create("RGB Profiles","Distance ("+unit+")", ylabel);
  ymax = getMax(r,g,b)+5;
  //if (ymax>255) ymax=255;
  Plot.setLimits(0, (r.length-1)*vw, 0, ymax);
  Plot.setColor("red");
  Plot.add("line", x, r);
  Plot.setColor("green");
  Plot.add("line", x, g);
  Plot.setColor("blue");
  Plot.add("line", x, b);
  Plot.update();

  function getMax(a,b,c) {
      max=a[0];
     for (i=0; i<a.length; i++) {
        max = maxOf(max,a[i]);
        max = maxOf(max,b[i]);
        max = maxOf(max,c[i]);
     }
     return max;
  }

-----Original Message-----
From: ImageJ Interest Group [mailto:[hidden email]] On Behalf Of Yumi Kumagai
Sent: Tuesday, April 09, 2013 12:50 PM
To: [hidden email]
Subject: plot profiles for two colors

Hi everyone

Cells were labeled with two fluorescent dyes, and photos for the two fluorescence were taken.
I want to compare plot profiles of the two colors for the exact same place.
Could you help me how to have plot profiles for each color using one line?

Thank you in advance.

Yumi Kumagai

--
ImageJ mailing list: http://imagej.nih.gov/ij/list.html

--
ImageJ mailing list: http://imagej.nih.gov/ij/list.html

[Glen MacDonald-2]

Dear Yumi
there are several possible approaches.  If the 2 channels are in separate images, Use Image>Color>Merge Channels…, then Make Composite.  Draw a line on the image, move the channel slider between channels and use the Analyze>Plot Profile command to create plots.   Simpler (sort of) is open the 2 images, draw a line on 1, get the Plot profile, then transfer the line ROI to the other image.  transfer by Edit>Selection>Restore Selection, or add the line to the ROIManager and apply it to as many images as you want.  the ImageJ documentation will provide more details.

Glen
Glen MacDonald
        Core for Communication Research
Virginia Merrill Bloedel Hearing Research Center
        Cellular Morphology Core
Center on Human Development and Disability
Box 357923
University of Washington
Seattle, WA 98195-7923  USA
[phone]
[hidden email]
[hidden email]





On Apr 9, 2013, at 10:49 AM, Yumi Kumagai <[hidden email]> wrote:

> Hi everyone
>
> Cells were labeled with two fluorescent dyes, and photos for the two
> fluorescence
> were taken.
> I want to compare plot profiles of the two colors for the exact same place.
> Could you help me how to have plot profiles for each color using one line?
>
> Thank you in advance.
>
> Yumi Kumagai
>
> --
> ImageJ mailing list: http://imagej.nih.gov/ij/list.html

--
ImageJ mailing list: http://imagej.nih.gov/ij/list.html

[LIM Soon Yew John (IMB)]

Hi Yumi,

If your images are multi-channels fluorescent images, you can use the macro below to plot the graph using the same line:
 
r=3; //channel number for the red channel
g=2; //channel number for the green channel
intensityBottom=0; intensityTop=4095; //Intensity Range for the plot
Stack.setChannel(r) //red channel
profile=getProfile();
Plot.create("2 Channels Line Plot", "Distance(Pixels)", "Intensity",profile);
Plot.setLimits(0, profile.length-1,intensityBottom,intensityTop); //set plot range
Stack.setChannel(g) //green channel
profile=getProfile();
Plot.setColor("green"); //color for Plot.add
Plot.add("line",profile);
Plot.setColor("red"); //color for first plot (Plot.create)

Best Regards,
John

________________________________________



On Apr 9, 2013, at 10:49 AM, Yumi Kumagai <[hidden email]> wrote:

> Hi everyone
>
> Cells were labeled with two fluorescent dyes, and photos for the two
> fluorescence
> were taken.
> I want to compare plot profiles of the two colors for the exact same place.
> Could you help me how to have plot profiles for each color using one line?
>
> Thank you in advance.
>
> Yumi Kumagai
>
> --
> ImageJ mailing list: http://imagej.nih.gov/ij/list.html

--
ImageJ mailing list: http://imagej.nih.gov/ij/list.html
--
ImageJ mailing list: http://imagej.nih.gov/ij/list.html